#!/usr/bin/gnuplot

set terminal postscript eps color enhanced solid font "Helvetica,16" size 8.6cm,7.5cm
set output "levelscheme.eps"
set termoption dash

f1 = 'lintrap_F2'
f2 = 'lintrap_F3'
f3 = 'circtrap_F2'
f4 = 'circtrap_F3'

####GENERAL SETTINGS####
set border linewidth 1.5
set samples 5000
set multiplot 
set pointsize 1.5
unset bar
set style fill solid 0.3 noborder
unset xtics 
set xrange [-10:40]

#set lmargin at screen 0.10
#set rmargin at screen 0.98

#bottom plot
set tmargin at screen 0.40
set bmargin at screen 0.01
set border 2
unset key 

set yrange [-27:9]
set ytics 10 nomirror out format "% g
set ylabel 'Light shift (MHz)' offset 0,6.5

set label 2 sprintf("5S_{1/2},F=2") at graph 0.85,0.62 font "Helvetica, 16"
set arrow from screen 0.138,0.402 to screen 0.168,0.417 nohead lw 1.5
set arrow from screen 0.138,0.39 to screen 0.168,0.405 nohead lw 1.5

f0(x)=0

plot f1 u (3*$1+3):($2*1e-6):(0.8) w xerr lw 4 ps 0 lt 1 lc 'black',\
f3 u (3*$1+30):($2*1e-6):(0.8) w xerr lw 4 ps 0 lt 1 lc 'black',\
f0(x) lt 2 lc 'black'

unset label 2
unset arrow

##top plot
set tmargin at screen 0.88
set bmargin at screen 0.41

set yrange [-9:29]
set ylabel ' '

set label 1 sprintf("(a)") at graph -0.1,1.1 font "Helvetica, 16"
set label 5 sprintf("5P_{3/2},F=3") at graph 0.85,0.12 font "Helvetica, 16"
unset xlabel
set label "{/Symbol p}-polarized trap" at graph 0.12,1.1 font "Helvetica, 16"
set label '{/Symbol s^+}-polarized trap' at graph 0.64,1.1 font "Helvetica, 16"
#set arrow from graph 0,0.9 to graph 0,1.05 lc 'black' lw 1.5  size screen 0.03,15,135


plot f2 u (3*$1+3):($2*1e-6):(0.8) w xerr lw 4 ps 0 lt 1 lc 'black',\
f4 u (3*$1+30):($2*1e-6):(0.8) w xerr lw 4 ps 0 lt 1 lc 'black',\
f0(x) lt 2 lc 'black'


unset multiplot   
unset output