#!/usr/bin/gnuplot

set terminal postscript eps color enhanced solid font "Helvetica,16" size 8.6cm,6.37cm
set output "../cooling_power_scan.eps"

f0 = 'lin_183MHz_powerscan'
f1 = 'lin_180MHz_powerscan'
f2 = 'lin_177MHz_powerscan' # data from 2017-06-15

f3 = 'circ_183MHz_powerscan' # data from 2017-06-19
f4 = 'circ_180MHz_powerscan'
f5 = 'circ_177MHz_powerscan'

####GENERAL SETTINGS####
blue_defined = '#0078FF'
set border linewidth 1.5
set samples 5000
set multiplot 
set pointsize 0.8
unset bar
#set style fill solid 0.3 noborder
set key samplen 0.5 at 840,160
set xtics nomirror
set ytics nomirror
set tmargin at screen 0.89

### left plot
set lmargin at screen 0.16
set rmargin at screen 0.55

set xlabel 'Cooling beam power ({/Symbol m}W)' offset 9,0
set ylabel 'Temperature ({/Symbol m}K)'
#set label 1 sprintf("(a)") at graph -0.05,1.065 font "Helvetica, 16"

set ytics 25
set yrange[00:165]	
set xrange[-20:840]
set xtics 250
set title '{/Symbol p}-polarized trap'

plot f0 u (2*$2):4:5 w ye lc rgb 'red' pt 5 lw 1.5 not,\
f0 u (2*$2):4 lc rgb 'red' pt 5 lw 1.5 t '{/Symbol D}=-2.3{/Symbol G_0}',\
f1 u (2*$2):4:5 w ye lc rgb blue_defined pt 65 lw 1.5 not '{/Symbol D}=-3.3{/Symbol G_0}',\
f1 u (2*$2):4 lc rgb 'white' pt 7 lw 1.5 not,\
f1 u (2*$2):4 lc rgb blue_defined pt 65 lw 1.5 t '{/Symbol D}=-3.3{/Symbol G_0}',\
f2 u (2*$2):4:5 w ye lc rgb 'black' pt 66 lw 1.5 not,\
f2 u (2*$2):4 w p lc rgb 'white' pt 9 ps 0.66 lw 1.5 not,\
f2 u (2*$2):4 w p lc rgb 'black' pt 66 lw 1.5 t '{/Symbol D}=-4.3{/Symbol G_0}'


### right plot
set lmargin at screen 0.59
set rmargin at screen 0.98
set xlabel '  '
#set label 1 sprintf("(b)") at graph -0.05,1.065 font "Helvetica, 16"
set ytics format " " 
unset ylabel
set title '{/Symbol s^+}-polarized trap'

plot f3 u (2*$2):4:5 w ye lc rgb 'red' pt 5 lw 1.5 not,\
f3 u (2*$2):4 lc rgb 'red' pt 5 lw 1.5 t '{/Symbol D}=-2.3{/Symbol G_0}',\
f4 u (2*$2):4:5 w ye lc rgb blue_defined pt 65 lw 1.5 not,\
f4 u (2*$2):4 lc rgb 'white' pt 7 lw 1.5 not,\
f4 u (2*$2):4 lc rgb blue_defined pt 65 lw 1.5 t '{/Symbol D}=-3.3{/Symbol G_0}',\
f5 u (2*$2):4:5 w ye lc rgb 'black' pt 66 lw 1.5 not,\
f5 u (2*$2):4 lc rgb 'white' pt 9 ps 0.66 lw 1.5 not,\
f5 u (2*$2):4 lc rgb 'black' pt 66 lw 1.5 t '{/Symbol D}=-4.3{/Symbol G_0}'

unset multiplot   
unset output
pause -1