#!/usr/bin/gnuplot

#Note: it is cumbersome to make hbar in gnuplot, a hotfix is to edit the label using inkscape with unicode input, remember to do so after replotting

set terminal postscript eps color enhanced solid font "Helvetica,16" size 8.6cm,9cm
set output "pgc_force.eps"
set termoption dash
####GENERAL SETTINGS####
blue_defined = '#0078FF'
set border linewidth 1.5
set samples 5000
set multiplot 
set style fill solid 0.3 noborder
unset key
c0 = '851nm/0mk_circulartrap_per.dat'
c1 = '851nm/0.1mk_circulartrap_per.dat'
c2 = '851nm/1mk_circulartrap_per.dat' 

c3 = '851nm/0mk_circulartrap_par.dat'
c4 = '851nm/0.1mk_circulartrap_par.dat'
c5 = '851nm/1mk_circulartrap_par.dat' 

l0 = '851nm/0mk_lineartrap_per.dat'
l1 = '851nm/0.1mk_lineartrap_per.dat'
l2 = '851nm/1mk_lineartrap_per.dat' 

l3 = '851nm/0mk_lineartrap_par.dat'
l4 = '851nm/0.1mk_lineartrap_par.dat'
l5 = '851nm/1mk_lineartrap_par.dat' 

set tmargin at screen 0.51
set bmargin at screen 0.12
set lmargin at screen 0.15
set rmargin at screen 0.54

#set label 1 sprintf("(c)") at graph -.4,1 font "Helvetica, 16"
set label 1 sprintf("(c)") at graph 0.78,0.88 font "Helvetica, 16"
set label 5 sprintf("x10") at graph 0.1,0.43 font "Helvetica, 16" tc rgb blue_defined

set xtics nomirror
set ytics nomirror 
set xlabel 'Velocity ({/Symbol G}/k_L)'

set ytics 3
set yrange[-7:7]
set xrange[-0.2:0.2]
set xtics 0.15

set ylabel 'Force  F_{z} (10^{-3}hk{/Symbol G})'

plot l3 u 1:($2*1e3) w l lw 2.5 lt 3 lc rgb 'black' t '0mK', \
l5 u 1:(10*$2*1e3) w l lw 2 lt 1 lc rgb blue_defined t '1mK'
#l4 u 1:(1*$2*1e3) w l lw 2 lc rgb 'purple' t '0.1mK',\

set lmargin at screen 0.58
set rmargin at screen 0.97

unset label 1
unset label 5
set label 2 sprintf("(d)") at graph 0.78,0.88 font "Helvetica, 16"
set label 6 sprintf("x5") at graph 0.1,0.56 font "Helvetica, 16" tc rgb blue_defined


unset ylabel
set ytics format " "

plot c3 u 1:($2*1e3) w l lw 2.5 lt 3  lc rgb 'black't '0mK', \
c5 u 1:(5*$2*1e3) w l lw 2 lt 1  lc rgb blue_defined t '1mK'
#c4 u 1:(1*$2*1e3) w l lw 2 lc rgb 'purple' t '0.1mK',\

set tmargin at screen 0.92
set bmargin at screen 0.55
set lmargin at screen 0.15
set rmargin at screen 0.54

unset label 2
unset label 6
set label 3 sprintf("(a)") at graph 0.78,0.88 font "Helvetica, 16"
set label 7 sprintf("x4") at graph 0.1,0.45 font "Helvetica, 16" tc rgb blue_defined
set title '{/Symbol p}-polarized trap'
set xtics format " "
set ytics format "% g"
unset xlabel
set ylabel 'Force F_{x} (10^{-3}hk{/Symbol G})'

set ytics 3
set yrange[-7:7]
set xrange[-0.2:0.2]
set xtics 0.15
plot l0 u 1:($2*1e3) w l lw 2.5 lt 3 lc rgb 'black't '0mK', \
l2 u 1:(4*$2*1e3) w l lw 2 lt 1 lc rgb blue_defined t '1mK'
#l1 u 1:($2*1e3) w l lw 2 lc rgb 'purple' t '0.1mK',\

set lmargin at screen 0.58
set rmargin at screen 0.97
unset label 3
unset label 7
set label 4 sprintf("(b)") at graph 0.78,0.88 font "Helvetica, 16"
set label 8 sprintf("x20") at graph 0.1,0.42 font "Helvetica, 16" tc rgb blue_defined
set title '{/Symbol s^+}-polarized trap'
set ytics format " "
#set title 'circular polarization'
unset ylabel
#set ylabel 'Force along x-axis F_{x} (hk {/Symbol G} x 1e-3)'
plot c0 u 1:($2*1e3) w l lw 2.5 lt 3 lc rgb 'black't '0mK', \
c2 u 1:(20*$2*1e3) w l lw 2 lt 1 lc rgb blue_defined t '1mK'
#c1 u 1:(5*$2*1e3) w l lw 2 lc rgb 'purple' t '0.1mK',\


unset multiplot   
unset output
pause -1