#!/usr/bin/gnuplot

set terminal postscript eps color enhanced solid font 'Helvetica, 16pt'\
 size 8.6cm, 6cm  dl .5
# set encoding utf8
set tmargin at screen 0.93

mean_offset = -3827495.39047

range_Dt = 600
unset bars
set output 'g2.eps'
set xrange [- range_Dt/2: range_Dt/2]
set ytics 5000
set yrange [0: 13000]

# set palette
load 'paired.pal'

# labels
# set label '-3827495' at graph 0.805, graph -0.105
# set xlabel font 'Helvetica, 16pt' "t' - t - @^{/=18-}{/Symbol d} (ns)" offset 0, 0.7
set xlabel font 'Helvetica, 16pt' "t' - t (ns)" offset 0, 0.7
set ylabel font 'Helvetica, 16pt' 'g^{(2)}' offset 1
set format y '%.0s%c'

# zero line
set arrow from 0,0 to 0,13000 nohead lw 1 dt '.'
set label "@^{/=18-}{/Symbol d} = -3.82749539(5) ms" at -5, 13700
# set label "@^{/=18-}{/Symbol d} = -3827495.39 ns" at -5, 13700

set key title "Fiber length" samplen 0
unset key

fit_lw = 2
point_sz = .5
arr_d = '-'

fib1_a=-8.361
fib1_b=8.361
fib1_y=12500
set arrow from fib1_a,fib1_y-500 to fib1_b,fib1_y-500 ls 1 lw fit_lw heads
set arrow from fib1_a,0 to fib1_a,fib1_y  ls 1 lw fit_lw dt arr_d nohead
set arrow from fib1_b,0 to fib1_b,fib1_y  ls 1 lw fit_lw dt arr_d nohead
set label ' 1.7m' at fib1_b+5, fib1_y - 500

fib2_a=-33.561
fib2_b=33.561
fib2_y=8700
set arrow from fib2_a,fib2_y to fib2_b,fib2_y ls 3 lw fit_lw heads
set arrow from fib2_a,0 to fib2_a,fib2_y ls 3 lw fit_lw dt arr_d nohead
set arrow from fib2_b,0 to fib2_b,fib2_y ls 3 lw fit_lw dt arr_d nohead
set label ' 6.7m' at fib2_b+5, fib2_y

fib3_a=-157.668
fib3_b=157.668
fib3_y=10500
set arrow from fib3_a,fib3_y to fib3_b,fib3_y ls 5 lw fit_lw heads
set arrow from fib3_a,0 to fib3_a,fib3_y  ls 5 lw fit_lw dt arr_d nohead
set arrow from fib3_b,0 to fib3_b,fib3_y  ls 5 lw fit_lw dt arr_d nohead
set label '31.7m' at fib3_b - 50, fib3_y + 500


fib4_a=-255.527
fib4_b=255.527
fib4_y=9800
set arrow from fib4_a,fib4_y to fib4_b,fib4_y ls 7 lw fit_lw heads
set arrow from fib4_a,0 to fib4_a,fib4_y  ls 7 lw fit_lw dt arr_d nohead
set arrow from fib4_b,0 to fib4_b,fib4_y  ls 7 lw fit_lw dt arr_d nohead
set label '51.7m' at fib4_b - 50, fib4_y + 500


plot \
	'fibre_00m_data.dat' u (($1-mean_offset)):2:3 with yerrorbar ls 2 lw 1 pt 6 ps point_sz title " 1.7m", \
	'fibre_05m_data.dat' u (($1-mean_offset)):2:3 with yerrorbar ls 4 lw 1 pt 6 ps point_sz title " 6.7m", \
	'fibre_30m_data.dat' u (($1-mean_offset)):2:3 with yerrorbar ls 6 lw 1 pt 6 ps point_sz title "31.7m", \
	'fibre_50m_data.dat' u (($1-mean_offset)):2:3 with yerrorbar ls 8 lw 1 pt 6 ps point_sz title "51.7m", \