#!/usr/bin/gnuplot

set terminal postscript eps color enhanced solid font 'Helvetica, 16pt' size 8.6cm, 6cm  dl .5
unset bars
unset key
set output 'g2.eps'
# set palette
load 'paired.pal'
set multiplot

o1 = -6636598.876041992
o2 = -6636599.089844113
o3 = -6636573.631719951
r1 = 63.76698800828308
r2 = 114.25485535804182
r3 = 114.2662843791768

top_margin = 0.05
bottom_margin = top_margin + 0.1 
dist_between_plots = 0.05
plot_height = (1 - top_margin - bottom_margin - 2*dist_between_plots)/3

set tmargin at screen 1 - top_margin
set label 1 "(a)" at screen 0.15, 1 - top_margin - 0.05
set label 2 "symmetric delay" at screen 0.9, 1 - top_margin - 0.05 right
set bmargin at screen 1 - top_margin - plot_height
set xtics nomirror; set ytics nomirror
range_Dt = 200
set xrange [- range_Dt/2: range_Dt/2]
set ytics 1000
set yrange [0: 1300]

set ylabel' ' #offset 1
set format y '%.0s%c'

point_sz = .5

set xtics auto
set xtics format ' '
plot [- range_Dt/2: range_Dt/2]\
	'g2_set0.dat' u (($1-o1)):2 every 10 ls 2 lw 1 pt 6 ps point_sz title "L = L' = L_o"

set tmargin at screen 1-top_margin-plot_height-dist_between_plots
set label 3 "(b)" at screen 0.15, 1-top_margin-plot_height-dist_between_plots - 0.05
set label 4 "symmetric delay (longer)" at screen 0.9, 1-top_margin-plot_height-dist_between_plots - 0.05 right
set bmargin at screen 1-top_margin-plot_height-dist_between_plots-plot_height
set xtics auto
set xtics format ' '
set ylabel'Normalized correlation g^{(2)}' offset -0.5
plot [- range_Dt/2: range_Dt/2]\
	'g2_set1.dat' u (($1-o1)):2 every 10 ls 2 lw 1 pt 6 ps point_sz title "L = L' = (L_o+5)"

set tmargin at screen 1-top_margin-plot_height-dist_between_plots-plot_height-dist_between_plots
set label 5 "(c)" at screen 0.15, 1-top_margin-plot_height-dist_between_plots-plot_height-dist_between_plots - 0.05
set label 6 "asymmetric delay" at screen 0.9, 1-top_margin-plot_height-dist_between_plots-plot_height-dist_between_plots - 0.05 tc lt 1 right
set bmargin at screen 1-top_margin-plot_height-dist_between_plots-plot_height-dist_between_plots-plot_height
set ytics 2000
set yrange [0: 3000]
set ylabel' ' #offset 1
plot [- range_Dt/2: range_Dt/2]\
	'g2_set2.dat' u (($1-o1)):2 every 10 ls 6 lw 1 pt 6 ps point_sz title "L = (L_o+10), L' = L_o"

set xtics format '%g'
set xlabel "{/Symbol t} - {/Symbol d}_{o} (ns)" offset 0, 0.3

replot