#!/usr/bin/gnuplot

set terminal postscript eps color enhanced solid font 'Helvetica, 16pt' size 8.6cm, 6cm  dl .5

# set encoding utf8

# mean_offset = 410035.24218755
# mean_std = 0.010297970354205651
# point_sz = 0.7
# data_f = 'offset_rtt_18secperpt.dat'

mean_offset = 410035.2353449103
mean_std = 6.7136e-3
point_sz = 0.9
data_f = 'offset_rtt_20_4_15.dat'

set output 'offsets.eps'

set multiplot

set lmargin at screen 0.13
set tmargin at screen 0.97
set bmargin at screen 0.4
set yrange [-35:35]

# labels
set ylabel '{/Symbol d} - ~{/Symbol d&{.}}{.6/Symbol \55 } (ps)' offset 1.1, 0

set label 1 '(a) offset' at screen 0.15, 0.91
set label 2 '(b) round-trip-time' at screen 0.15, 0.32

set xrange [-1:29.9]
set xtics auto
set xtics format ' '
set ytics format '% 4g'
set arrow from 10,0 to 10,6.7 ls 8 lw 3 heads
set label "precision" at 10.5,3.5

plot \
0 notitle lc 'blue' lw 3, \
(mean_std * 1e3) notitle lc 'blue' lw 2 dashtype 2, \
(- mean_std * 1e3) notitle lc 'blue' lw 2 dashtype 2, \
data_f using ($0):(($8-mean_offset)*1000) notitle with points pt 6 ps point_sz lc rgb "black"

# set arrow from 20,(-mean_std * 1e3) to 20,(mean_std * 1e3) ls 1 lw 2 heads
# show arrow

unset arrow
unset label
set tmargin at screen 0.38
set bmargin at screen 0.14
set xlabel "Block" offset 0, 0.4
set ylabel '{/Symbol D}T (ns)' offset 1.1, 0
set ytics 250
set yrange [0:580]
set xtics format '%g'

plot data_f using ($0):($3) notitle with points pt 6 ps point_sz lc rgb "red"