#set terminal postscript eps color enhanced solid font "Helvetica,15" size 5cm,4cm
set terminal pdf color enhanced solid font "Helvetica,12" size 5.2cm,5.2cm
set colorsequence classic
#set output 'modetransmission.eps'
set output "modetransmission.pdf"

set multiplot

set samples 5000
set xrange [-1.8:0.4]
set yrange [0:1.4]
unset key
set xtics ("{/Symbol n}_{q,0,0}" 0) nomirror
unset ytics
set xlabel 'frequency'
set ylabel 'cavity transmission'
R=0.93
f(x)=(1-R)**2/(1+R**2-2*R*cos(2*x))
set arrow 1 front from -0.25,0.1 to 0,0.1
set arrow 2 front from -0.25,0.1 to -0.5,0.1
set label 5 front "2{/Symbol D}{/Symbol n}_{tr}" font "Helvetica,10" at -0.28,0.18 center
plot f(x)+1./5*f(x+0.5)+1./15*f(x+1)+1./30*f(x+1.5) lw 2 dt 1 lc 9

unset label 5
unset arrow 1
unset arrow 2
f0(x,y)=exp(-2*(x**2+y**2))
f1(x,y)=exp(-2*(x**2+y**2))*(-2*(x**2+y**2)+1)**2
f2(x,y)=exp(-2*(x**2+y**2))*(0.5*(2*(x**2+y**2))**2-2*(2*(x**2+y**2))+1)**2
f3(x,y)=exp(-2*(x**2+y**2))*(-(2*(x**2+y**2))**3/6+9*(2*(x**2+y**2))**2/6-3*(2*(x**2+y**2))+1)**2
unset style fill
set pm3d map
set palette gray
set palette negative
set cbrange [0:0.6] #saturation factor
set isosamples 50
unset xtics
unset ytics
unset cbtics
unset xlabel
unset ylabel
unset cblabel
set xrange [-2.7:2.7] 
set yrange [-2.7:2.7] reverse
unset colorbox
unset border

set bmargin at screen 0.77
set tmargin at screen 0.92
set lmargin at screen 0.695
set rmargin at screen 0.845
set label 1 front "LG_{00}" font "Helvetica,10" at screen 0.77,0.77 center
splot f0(x,y) not

set bmargin at screen 0.42
set tmargin at screen 0.57
set lmargin at screen 0.515
set rmargin at screen 0.665
set label 2 front "LG_{10}" font "Helvetica,10" at screen 0.59,0.4 center
splot f1(x,y) not

set bmargin at screen 0.42
set tmargin at screen 0.57
set lmargin at screen 0.335
set rmargin at screen 0.485
set label 3 front "LG_{20}" font "Helvetica,10" at screen 0.41,0.4 center
splot f2(x,y) not

set bmargin at screen 0.42
set tmargin at screen 0.57
set lmargin at screen 0.155
set rmargin at screen 0.305
set label 4 front "LG_{30}" font "Helvetica,10" at screen 0.23,0.4 center
splot f3(x,y) not

unset multiplot

pause -1