reset
set terminal postscript eps color enhanced solid font "Helvetica,18" size 8.6cm, 12cm

set output "fig4abc.eps"
set termoption dash


f1 = 'p30_p.txt'
f3= 'cc1.txt'
f2 = 'm30_p.txt'

set border linewidth 1.5
set multiplot 
set samples 5000

unset bar
unset key

set style fill solid 0.3 noborder
set tmargin at screen 0.37
set bmargin at screen 0.1
set lmargin at screen 0.21
set rmargin at screen 0.9
set label 1 "c)" at graph -0.3,1.0
set label 4 "d = -183 nm" at graph 0.05,0.93



set pointsize 1
set xlabel 'cavity detuning (MHz)'
set ylabel 'transmission (%)'

set yrange [0:50]
set xrange [-150:100]
set ytics 10 nomirror format "%g" 
set xtics 50 nomirror
set bar 1 

lorentz_T(x) = T0 / ( 4*( (x-x0) / (gamma0) )**2 + 1 ) + T1 / ( 4*( (x-x1) / (gamma1) )**2 + 1 )-Tbg
lorentz_T_1p(x) = T0 / ( 4*( (x-x0) / (gamma0) )**2 + 1 ) -Tbg
T0=40
Tbg=10
gamma0=15
x0=1
fit [-100:100] lorentz_T_1p(x) f3 u 1:(100*$2) via x0,gamma0,T0,Tbg
set label 2 "unstable \n  mode" at graph 0.05,0.43
set label 5 " {/Symbol g_{1}} = 60.7(1) MHz" at graph 0.4,0.4
plot f3 using 1:($2*100) w l lt 2 lw 4 lc rgb "red",(lorentz_T_1p(x+x0)) dashtype 3 lc rgb "black" lw 4 not

#set yrange [0:50]
set tmargin at screen 0.67
set bmargin at screen 0.4
set label 1 "b)" at graph -0.3,1.0
set label 2 "LG_{00}" at graph 0.09,0.45
set label 4 "d = 207 nm" at graph 0.05,0.93
set ytics 10 nomirror format "%g" 
set xtics 50 nomirror

unset xlabel
unset xtics
set ylabel 'transmission (%)'
T0=40
Tbg=10
gamma0=15
x0=1
x1=-70
T1=10
gamma1=15
fit [-100:100] lorentz_T(x) f1 u 1:(100*$2) via x0, gamma0,T0,Tbg,x1,T1,gamma1
set label 5 " {/Symbol g_{1}} = 22.55(6) MHz" at graph 0.4,0.93
plot f1 using 1:($2*100) w l lt 2 lw 4 lc rgb "red",(lorentz_T(x+x0)) dashtype 3 lc rgb "black" lw 4 not

set tmargin at screen 0.97
set bmargin at screen 0.7


lorentz_T(x) = T0 / ( 4*( (x-x0) / (gamma0) )**2 + 1 ) + T1 / ( 4*( (x-x1) / (gamma1) )**2 + 1 )-Tbg
T0=40
Tbg=10
gamma0=15
x0=1
x1=-70
T1=10
gamma1=15
fit [-100:100] lorentz_T(x) f2 u 1:(100*$2) via x0, gamma0,T0,Tbg,x1,T1,gamma1
#set arrow from 0, graph 0 to 3, graph 0 nohead
#set arrow from 0, graph 0 to 0, graph 1 nohead dt 2
#set arrow from -62, graph 0 to -62, graph 1 nohead dt 2
#set arrow from 0,45, graph 0 to -62,45, graph 1 lt 1 lw 1.5 lc rgb "black" heads 
set style line 1 lt 2 lc rgb "black" lw 3
set label 1 "a)" at graph -0.3,1.0
set label 2 "LG_{01}" at graph 0.09,0.5
set label 3 "LG_{00}" at graph 0.28,0.5
set label 4 "d = 597 nm" at graph 0.05,0.93
set label 5 " {/Symbol g_{1}} = 22.43(5) MHz" at graph 0.4,0.93
set label 6 "{/Symbol g_{2}} = 21.8(1) MHz" at graph 0.09,0.27
plot f2 using 1:($2*100)  w l lt 2 lw 4 lc rgb "red",(lorentz_T(x+x0)) dashtype 3 lc rgb "black" lw 4