#!/usr/bin/gnuplot

set terminal postscript eps color enhanced solid font "Helvetica,18" size 8.6cm, 6cm
set output "figure5.eps"

#################################
#######
####GENERAL SETTINGS####
set border linewidth 1.5
set samples 5000
set multiplot 
#set bar 2
unset bar
unset key
#set style fill solid 0.3 noborder

###########################
#####            #####

unset key

unset xtics
unset xlabel
unset ytics
unset ylabel
unset key

set border 15
set tmargin at screen 0.53
set bmargin at screen 0.18
set lmargin at screen 0.20
set rmargin at screen 0.95

f1 = 'atom_spectrum/dat/T_atom'
f2 = 'atom_spectrum/dat/fit_T_atom'
f3 = 'atom_spectrum/dat/T_woatom'
f4 = 'atom_spectrum/dat/fit_T_woatom'

set ytics 0.5 nomirror format "%g" 
set xtics 50 nomirror
set xrange [-130:130]
set yrange [0:1.4]
set xlabel 'detuning {/Symbol D}_c/2{/Symbol p} (MHz)'
set ylabel 'transmission (%)'
unset label

unset title
unset grid 
unset key

max_T_cts = 30
max_T = 1.3 # max transmission in percent

## transmission fit ; no atom
gamma0=100
T0=1.3
x0=23


lorentz_T(x) = T0 / ( 4*( (x-x0) / (gamma0) )**2 + 1 )
fit [-200:200] lorentz_T(x) f3 u 1:($2/max_T_cts*max_T):($3/max_T_cts*max_T) via x0, gamma0, T0

## transmission fit ;  atom
i = {0.0,1.0}
deltaA = 1
gamma=3
kappa=gamma0/2
g=5

Tran(x)= max_T*abs( kappa* (i*(deltaA+x-x0) + gamma)/ ( (i*(x-x0)+kappa)*(i*(deltaA+x-x0)+gamma)+ g**2))**2
fit [-200:200] Tran(x) f1 using 1:($2/max_T_cts*max_T):($3/max_T_cts*max_T) via deltaA,g
#################################


plot f3 using ($1-x0):($2/max_T_cts*max_T):($3/max_T_cts*max_T) w yerr pt 7 lc rgb "grey",  lorentz_T(x+x0) lc rgb "grey" lw 2 not, f1 using ($1-x0):($2/max_T_cts*max_T):($3/max_T_cts*max_T) w yerr pt 7 ps 1.0 lc rgb "red", Tran(x+x0) lc rgb "red" lw 2 not


set border 15
set tmargin at screen 0.95
set bmargin at screen 0.60
set xtics format ""
unset xlabel
set label 1 "a)" at graph -0.26,1.08 
set label 2 "b)" at graph -0.26,-0.08


f1 = 'atom_spectrum/dat/R_atom'
f2 = 'atom_spectrum/dat/fit_R_atom'
f3 = 'atom_spectrum/dat/R_woatom'
f4 = 'atom_spectrum/dat/fit_R_woatom'

set ytics 0.5 nomirror format "%g" 

set xrange [-130:130]
set yrange [52:100]
set ytics 20
set ylabel 'reflection (%)'

unset title
unset grid 
unset key

max_R = 33.75

max_R_watom = 34.4

##### reflection fit; no atom
max_R = 35.75
gamma1=100
eta=38
x0=23

lorentz_R(x) = max_R* (100 - eta / ( 4*( (x-x0) / (gamma1) )**2 + 1 ) )
fit [-200:200] lorentz_R(x) f3 u 1:(100*$2):(100*$3) via x0, gamma1, eta,max_R

#############
## reflection fit ;  atom
i = {0.0,1.0}
max_R_watom = 37
deltaA = 1
gamma=3
kappa=gamma1/2
g0=5

c=3e8
len=11e-3
kappa_l =  c/2/len/2* 0.005 *1e-6/(2*pi) 

Refl(x)= max_R_watom*100* ( abs(1- 2*kappa_l* (i*(deltaA+x-x0) + gamma)/ ( (i*(x-x0)+kappa)*(i*(deltaA+x-x0)+gamma)+ g0**2) )**2 )
fit [-200:200] Refl(x) f1 using 1:(100*$2):(100*$3) via deltaA,max_R_watom,g0


plot f3 using ($1-x0):(100*$2/max_R):(100*$3/max_R) w yerr pt 7 lc rgb "grey", (lorentz_R(x+x0)/max_R) lc rgb "grey" lw 2 not,\
f1 using ($1-x0):(100*$2/max_R_watom):(100*$3/max_R_watom) w yerr pt 7 ps 1.0 lc rgb "red", (Refl(x+x0)/max_R_watom) lc rgb "red" lw 2 not



unset multiplot
unset output
#pause -1