set terminal postscript eps color enhanced solid font "Helvetica,18" size 8.6cm, 8cm

set output "figure3.eps"
set termoption dash

f1 = "dark_lftm/dark_lifetime_data.dat" 

set border linewidth 1.5
set multiplot 
set samples 5000
unset bar
unset key
set style fill solid 0.3 noborder
set tmargin at screen 0.44
set bmargin at screen 0.125
set lmargin at screen 0.21
set rmargin at screen 0.9
set label 1 "b)" at graph -0.3,1.05

set yrange [0:100]
set ytics 25 nomirror
set ytics format "%3g"
set xtics 100 nomirror
set pointsize 1
#set title "Atom Lifetime"
set xlabel "waiting time {/Symbol t} (ms)"
set ylabel "survival probability (%)" 
set bar 1 

f(x) = a* exp(-x/t0) 
a = 1; t0 = 200
fit f(x) f1 using 1:4 via a,t0

plot [0:350] (100*f(x)) lc rgb "black" lw 2, f1 using 1:(100*$4):(100*$5) w yerr pointtype 7 lc rgb "red" lw 2 lt 1

set tmargin at screen 0.98
set bmargin at screen 0.62
set label 2 "a)" at graph -0.3,1
#f2 = "rawdata/flur2_1.dat" 
f2 = "typical signals/raw/selected_traces/trace_9.dat"
threshold(x) = 90

set yrange [0:120]
set xrange [0:5]
set ytics 50 nomirror
set xtics 1 nomirror
set pointsize 1
#set title "Atom Lifetime"
set xlabel "time (s)"
set ylabel "photoevents in 10ms" 
set label 1 "threshold" at graph 0.7,0.66

plot f2 using ($1-426):($2*10) w l lc rgb "red" lw 2, threshold(x) w l lc rgb "black" lw 2 lt 3