#!/usr/bin/gnuplot

set terminal postscript eps color enhanced solid font "Helvetica,18" size 8.6cm, 12cm
set output "figure2.eps"

#################################
#######
####GENERAL SETTINGS####
set border linewidth 1.5
set samples 5000
set multiplot 
#set bar 2
unset bar
unset key
#set style fill solid 0.3 noborder

###########################
#####            #####

f1 = '2d_T_profile/dat/2d_T_profile_2.dat'

set pm3d map
#set pm3d interpolate 0,0
#set palette defined (0 0 0 0.5, 1 0 0 1, 2 0 0.5 1, 3 0 1 1, 4 0.5 1 0.5, 5 1 1 0, 6 1 0.5 0, 7 1 0 0, 8 0.5 0 0)
set palette rgb 34,35,36
unset key

set lmargin at screen 0.3
set rmargin at screen 0.7
set tmargin at screen 0.40
set bmargin at screen 0.10

set xtics 50
set ytics 50
set cbtics (0,0.5,1)
set xlabel 'y-axis, mirror position (nm)'
set ylabel 'x-axis, mirror position (nm)'
set cblabel 'relative transmission'
set xrange [-70:70] 
set yrange [-70:70]
set cbrange [0:1]
set colorbox vertical user origin .78,0.1235 size 0.03,0.25

splot f1 u ($1*500):($2*500):($3/30/30) 

unset xtics
unset xlabel
unset ytics
unset ylabel
unset key
unset pm3d 
set border 15
set tmargin at screen 0.74
set bmargin at screen 0.54
set lmargin at screen 0.20
set rmargin at screen 0.95

set ytics 0.5 nomirror format "%g" 
set xtics 40 nomirror
set xrange [-130:130]
set yrange [0:1.4]
set xlabel 'detuning {/Symbol D}_c/2{/Symbol p} (MHz)'
set ylabel 'transmission (%)'
unset label

unset title
unset grid 
unset key

set arrow 5 heads from 0,0 to 0,1.3 lw 1.2

f3 = '../figure5/atom_spectrum/dat/T_woatom'
f4 = '../figure5/atom_spectrum/dat/fit_T_woatom'
max_T_cts = 30
max_T = 1.3 # max transmission in percent

gamma0=100
T0=1.3
x0=23

lorentz_T(x) = T0 / ( 4*( (x-x0) / (gamma0) )**2 + 1 )
fit [-200:200] lorentz_T(x) f3 u 1:($2/max_T_cts*max_T):($3/max_T_cts*max_T) via x0, gamma0, T0

plot f3 using ($1-x0):($2/max_T_cts*max_T):($3/max_T_cts*max_T) w yerr pt 7 lc rgb "black", lorentz_T(x+x0) lc rgb "black" lw 2 not

set border 15
set tmargin at screen 0.97
set bmargin at screen 0.77
set xtics format ""
unset xlabel

set label 1 "c)" at graph -0.26,-1.7 
set label 2 "{/Symbol h}=41.7(5)%" at graph 0.51,0.84 
set label 3 "a)" at graph -0.26,1.07 
set label 4 "b)" at graph -0.26,-0.08

f3 = '../figure5/atom_spectrum/dat/R_woatom'
f4 = '../figure5/atom_spectrum/dat/fit_R_woatom'

max_R = 33.75
gamma1=100
eta=38
x0=23

lorentz_R(x) = max_R* (100 - eta / ( 4*( (x-x0) / (gamma1) )**2 + 1 ) )
fit [-200:200] lorentz_R(x) f3 u 1:(100*$2):(100*$3) via x0, gamma1, eta,max_R

set ytics 0.5 nomirror format "%g" 
set xrange [-130:130]
set yrange [52:100]
set ytics 20
set ylabel 'reflection (%)'

set label 5 "T_{max}=1.3%" at graph 0.51,-0.95 
set arrow 5 heads from 0,100 to 0,59 lw 1.2

unset title
unset grid 
unset key

plot f3 using ($1-x0):(100*$2/max_R):(100*$3/max_R) w yerr pt 7 lc rgb "black", (lorentz_R(x+x0)/max_R) lc rgb "black" lw 2 not


unset multiplot
unset output
#pause -1