#### Styles ####
set style line 1 lc 1 lw 1 ps 1.5
set style line 2 lc 3 lw 1 ps 1.5
set style line 3 lc 4 lw 2 ps 1.5
set style line 4 lc 2 lw 2 ps 1.5

#set arrow 1 from graph 0.5,0 to graph 0.5,1 lt 0 lw 2 nohead
set terminal postscript enhanced color eps size 20cm,15cm 
set output 'cavity_transmission.eps'
unset xlabel
unset xtics
unset ylabel
unset ytics
unset y2label
unset y2tics

set multiplot

set xrange [-10:9]
set yrange [0:20]
set y2range [-7:10]
set size 1,1
set origin 0,0

set xlabel 'frequency (GHz)' offset 0,-2.5 font 'Helvetica, 40pt'
set ylabel 'cavity transmission %' font 'Helvetica, 40pt' offset -5.5,0
set y2label 'error signal voltage (V)' font 'Helvetica, 40pt' offset 5,0 

set format x "%4.0f"
set xtics -10,2,10 offset 0,-0.5 font 'Helvetica, 40pt'
set ytics 2,4,20 nomirror font 'Helvetica, 40pt'
set y2tics -7,2,10 font 'Helvetica, 40pt'

set key off
set object 1 rectangle from 7,0 to 8,20 fs empty border rgb "black"

plot '../raw_data_files/cavity_combined.txt' u ($1*502.40100):(($2*1500*100)/($3*3300)) every 10 w l lt 1 lw 3 axes x1y1, \
    '../raw_data_files/error_signal.txt' u (($1*502.40100)-3.2):($2/2) every 50 w l lt 1 lc 3 lw 3 axes x1y2

unset xtics
unset ytics
unset xlabel
unset ylabel
set size 0.33,0.33
set origin 0.48,0.65
set format x "%4.1f"
set xrange [7:8]
set xtics 7,0.2,8 offset 0,-0.5 font 'Helvetica, 30pt'
set ytics 2,4,20 nomirror font 'Helvetica, 30pt'
set yrange [0:20]
unset y2label
unset y2tics
set label 1 'FWHM = 25 MHz' at 7.05,14 font 'Helvetica, 22pt'
plot '../raw_data_files/cavity_combined.txt' u ($1*502.40100):(($2*1500*100)/($3*3300)) w l lt 1

unset multiplot