# fit parameters and format modified by A. Cere, 2015.05.12

set terminal postscript eps color enhanced solid font "Helvetica,16" size 8.6cm, 5.5cm
set output 'plot_beat.eps'
set border 3
set nobar
set size 1,1
set sample 1000,1000
set colors classic

# f(x)=(x>=0?bg+((a1**2)*exp(-2*(x-x0)/t1))+((a2**2)*exp(-2*(x-x0)/t2))+(2*a1*a2*exp(-(x-x0)*((1/t1)+(1/t2)))*cos((2*3.14*0.266*(x-x0))+p)):1)
# x0=0;a1=300;a2=300;t1=10.2;t2=26;p=0.1;bg=2
# fit [0:] f(x) 'ff.dat' u 1:2 via a1,a2,p

g(x)= g*(2*r*exp(-(x-x0)*(1/(2*t0)+1/(2*t1)))*cos(fr*(x-x0)+p) + exp(-(x-x0)/t0) + r**2*exp(-(x-x0)/t1))
e(x)= g * (2*r*cos(p)+r**2+1) * exp((x-x0)/tr)
bg = 3.80166369

# Parameters obtained by fit
x0 = 0.9
g = 20.2191184
r = 1.16235576
p = 283.733371/180*pi
tr = 0.2
t0 = 5.6
t1 = 13.0
fr = 1.671327

set label "Selected polarizations:" at first 10,105
set label font "Helvetica,16" "signal: {/Symbol \367} L {/Symbol \361}" at first 10, first 90
set label font "Helvetica,16" "idler: (0.7+0.57i){/Symbol \367} H {/Symbol \361}+(0.41i){/Symbol \367} V {/Symbol \361}" at first 10, first 75
set xlabel font "Helvetica,18" "{/Symbol D}t (ns)"
set ylabel font "Helvetica,18" "Coincidence events" 

set xtics nomirror
set ytics nomirror
plot [-10:40]'ff.dat' every 2 u 1:2:(sqrt($2))w yerrorbars notitle pt 7 ps 0.5, g(x)*(x>x0) + e(x)*(x<x0) + bg lc rgb  "#007700" lw 3 lt 2 notitle