set terminal postscript eps color enhanced solid font "Helvetica,14" size 8.6cm, 5.5cm
set output 'plot_beat.eps'
set border 3
set nobar
set size 1,1
set sample 1000,1000

f(x)=(x>=0?bg+((a1**2)*exp(-2*(x-x0)/t1))+((a2**2)*exp(-2*(x-x0)/t2))+(2*a1*a2*exp(-(x-x0)*((1/t1)+(1/t2)))*cos((2*3.14*0.266*(x-x0))+p)):1)
x0=0;a1=300;a2=300;t1=10.5;t2=27;p=0.1;bg=1
fit [0:] f(x) 'ff.dat' u 1:2 via a1,a2
set label font "Helvetica,16" "signal: {/Symbol \367} L {/Symbol \361}" at first 10, first 90
set label font "Helvetica,16" "idler: (0.7+0.57i){/Symbol \367} H {/Symbol \361}+(0.41i){/Symbol \367} V {/Symbol \361}" at first 10, first 75
#set label font "Helvetica,12" "1/{/Symbol d}f" at first 9.9, first 90
set xlabel font "Helvetica,18" "{/Symbol D}t_{is} (ns)"
set ylabel font "Helvetica,18" "Counts in 5 hours" 
set xtics nomirror
set ytics nomirror
plot 'ff.dat'u 1:2:(sqrt($2))w yerrorbars notitle pt 7 ps 0.5,f(x) lc rgb "#007700" lw 3 lt 2 notitle
# 'coincidence_left.dat' u ($1+5.5):($2*110) w l lc rgb "#555555" lw 2 lt 3 notitle, #’coincidence_left.dat' u ($1+9.2):($2*110) w l lc rgb "#555555" lw 2 lt 3 notitle