# plot with labels generated using latex
# to obtain the final PDF file run in sequence:
# gnuplot plot_phase_latex.gnu
# latex plot_phase.tex
# to generate a PDF:
# dvipdf plot_phase.dvi plot_phase.pdf
# to generate EPS instead use:
# dvips -E -o plot_phase.eps plot_phase.dvi


set terminal epslatex 'phv' standalone color colortext 8 size 11cm, 7cm
set output 'plot_phase.tex'
set sample 1000,1000
set border 3
set nobar
set multiplot layout 3,1
set colors classic

# Fitting function
f(x)=(x>=0?bg+((g**2)*(r**2)*exp(-(x-x0)/t1))+((g**2)*exp(-(x-x0)/t2))+(2*(g**2)*r*exp(-(x-x0)*((1/(2*t1))+(1/(2*t2))))*cos((2*pi*0.266*(x-x0))+p)):1)

### alignment aids
TOP=0.98
BOTT = 0.03
DY = 0.29
PTSZ = 0.25

LABX = -9
LABY = 550

### Bottommost plot, with labels
set tmargin at screen TOP-3*DY+PTSZ+BOTT
set bmargin at screen TOP-3*DY+BOTT
set ylabel ' ' offset 1
set ytics 200
set xtics 5
set xtics nomirror
set ytics nomirror
set format y "%4.0f"
set format x "%2.0f"
set xlabel '$\Delta$t (ns)'
set format '%g'

# set label 3 'Coincidence events' at first -15, first 600 rotate by 90
set label 1 'signal: $|L\rangle$' at first 25, first 400
set label 2 'idler: $|L\rangle$' at first 25, first 250
set label 3 '(c)' at first LABX, first LABY

x0=0;g=10;r=2.0;t1=5.6;t2=13.1;p=pi;bg=40
fit [0:] f(x) 'pump_HV_out_LL_processed.dat' u ($1-459.2):2 via g,bg
plot [-10:40] 'pump_HV_out_LL_processed.dat' u ($1-459.2):2:(sqrt($2)) w yerrorbars notitle pt 7 ps 0.5 lc rgb "red", f(x) lc rgb "#007700" lw 2 lt 2 notitle

#### Middle plot
set tmargin at screen TOP-2*DY+PTSZ+BOTT
set bmargin at screen TOP-2*DY+BOTT
set ylabel 'Coincidence events' offset 1
unset xlabel
set ytics 200
set xtics 5
set format x ""
set xtics nomirror
set ytics nomirror
# set format x ""
set label 1 'signal: $|V\rangle$' at first 25, first 400
set label 2 'idler: $|H\rangle$' at first 25, first 250
set label 3 '(b)' at first LABX, first LABY

x0=0;g=10;r=0.7;t1=5.6;t2=13.1;p=0.0;bg=0.01
fit [-0:] f(x) 'pump_HV_out_VH_processed.dat' u ($1-459.2):2 via g,bg
plot [-10:40]'pump_HV_out_VH_processed.dat' u ($1-459.2):2:(sqrt($2)) w yerrorbars notitle pt 7 ps 0.5 lc rgb "red", f(x) lc rgb "#007700" lw 2 lt 2 notitle


#### Topmost plot
set tmargin at screen TOP-DY+PTSZ+BOTT
set bmargin at screen TOP-DY+BOTT
set ytics 200
set xtics 5
set format x ""
unset xlabel
set ylabel  ' ' offset 1
set xtics nomirror
set ytics nomirror

x0=0;g=0.1;r=35;t1=5.6;t2=13.1;p=pi;bg=15
set label 1 'signal: $|H\rangle$' at first 25, first 400
set label 2 'idler: $|V\rangle$' at first 25, first 250
set label 3 '(a)' at first LABX, first LABY

fit [0:] f(x) 'out_HV_new_4ns.dat' u ($1-459.2):2 via g,bg
plot [-10:40][0:600] 'out_HV_new_4ns.dat' u ($1-459.2):2:(sqrt($2)) w yerrorbars notitle pt 7 ps 0.5,f(x) lc rgb "#007700" lw 2 lt 2 notitle


unset multiplot