#!/usr/bin/gnuplot
# plots the tx curves without atom

## input file ##
infile_1='non_reversed_with_alternating_09_26_onwards_combined_histo_tx_1ns'
infile_2='2015_11_11-11_17_non_reversed_combined_histo_tx_1ns'
infile_3='2015_10_30-11_03_non_reversed_combined_histo_tx_1ns'
infile_4='2015_11_03-11_06_non_reversed_combined_histo_tx_1ns'
infile_5='2015_11_06-11_11_non_reversed_combined_histo_tx_1ns'
t_offset=909.5
t_offset_13ns=881.5 # offset for 13.5ns photons

eta_1 = 3.68878e-03
eta_2 = 3.46768e-03
eta_3 = 4.92813e-03
eta_4 = 4.28547e-03
eta_5 = 5.26833e-03
#------------------------------------
set terminal postscript eps color enhanced solid font "Helvetica,22" size 12.6cm,8cm
set output "photon_g2.eps"

set border linewidth 1.5
set border 3
set encoding utf8


set key at graph 1.05,1 spacing 1.1 samplen 0

set xtics 20 nomirror
set ytics 0.04 nomirror format "%1.2f"
set xr [-6:41]
set xlabel "Time from heralding event, {/Times-Italic t_i} (ns)"
set ylabel "Normalized coincidences"

# loading the color palette
load "dark2.pal"

# global point size adjustment
pt_size = 1.1
set nobar


plot infile_1 u (($2-t_offset_13ns)):($9/eta_1):($10/eta_1)  with yerrorlines ls 8 pt 7 ps pt_size t "1.96(1) {/Symbol G}_0",\
    infile_2 u (($2-t_offset)):($9/eta_2):($10/eta_2)  with yerrorlines ls 7 pt 7 ps pt_size t "2.61(1) {/Symbol G}_0",\
    infile_3 u (($2-t_offset)):($9/eta_3):($10/eta_3)  with yerrorlines ls 3 pt 7 ps pt_size t "3.76(2) {/Symbol G}_0",\
    infile_4 u (($2-t_offset)):($9/eta_4):($10/eta_4)  with yerrorlines ls 2 pt 7 ps pt_size t "4.76(3) {/Symbol G}_0",\
    infile_5 u (($2-t_offset)):($9/eta_5):($10/eta_5)  with yerrorlines ls 1 pt 7 ps pt_size t "6.09(5) {/Symbol G}_0"