#set multiplot layout 2,1

filename="processed_histogram_with_yerror_bars/results.sorted"
filename8="processed_histogram_with_yerror_bars_8ns_bin/results.sorted"
#rootdir="/mnt/buffalo/"
rootdir="./"
square="sq_pulse/"
exp="exp_pulse/vary_photon_number_perkin_elmer_"

#### Columns for square pulse ####
data_filename=1
p_tran=2
p_tran_err=3
od_used=4
photon_no=5
photon_err=6
p_refl_flou=7
p_refl_flou_err=8
p_refl_flou_bg=9
p_refl_flou_bg_err=10
p_refl_scat=11
p_refl_scat_err=12
flou_lifetime=13
flou_lifetime_err=14
max_p_refl=15
max_p_refl_err=16

#### "Columns for exponential pulse ####
exp_risetime=17
exp_risetime_err=18
fit_lambda=19
fit_lambda_err=20
fit_photon_no=21
fit_photon_err=22

#### End "Columns ####

currentdir="`pwd`"
cd rootdir

#### Styles ####

set style line 1 lc 1 lw 3
set style line 2 lc 3 lw 3
set style line 3 lc 4 lw 3

#### Normalising detection probablity to rho 22 ####
timebin=1.0
timebin8=8.0
lifetime=26.3
effiency=0.3
overlap=0.03
rho(x)=x/(overlap*effiency*(timebin/lifetime))
rho_d(x)=x/(overlap*effiency)
rho8(x)=x/(overlap*effiency*(timebin8/lifetime))
rho_d8(x)=x/(overlap*effiency)


unset logscale xy
set logscale x
set key left


# #### Plotting stuff vs average photon number, for optimal bandwidths

y_stretch=1e0
unset label 1
set terminal postscript enhanced color eps size 8.6cm,5cm font "Helvetica,16pt"
set yrange [0:1]
set xlabel '{/Symbol \341}N{/Symbol \361}' offset 0,0.3
set ylabel 'P_{e,max}' offset 1,0
unset key
set key at 20,0.2

set format x "10^{%L}"

set label 1 at 50, 0.25 "square\npulse\n{/Symbol t} = 20 ns"
set label 2 at 2,0.45 "exponential\npulse\n{/Symbol t} = 15 ns"

set output '../rho22_max_optimal_bandwidth_a.eps'

plot square.'20ns/'.filename u (column(photon_no)):(rho(column(max_p_refl))*y_stretch):photon_err:(rho(column(max_p_refl_err))*y_stretch) w xyerror axes x1y1 notitle pt 7 ps 1 lt 1 lc 1 lw 1,\
      exp.'15ns/'.filename u (column(photon_no)):(rho(column(max_p_refl))*y_stretch):photon_err:(rho(column(max_p_refl_err))*y_stretch) axes x1y1 w xyerror notitle pt 6 ps 1 lt 1 lc 3 lw 1 

unset output