#set multiplot layout 2,1

filename="processed_histogram_with_yerror_bars/results.sorted"
filename8="processed_histogram_with_yerror_bars_8ns_bin/results.sorted"
#rootdir="/mnt/buffalo/"
rootdir="./"
square="sq_pulse/"
exp="exp_pulse/vary_photon_number_perkin_elmer_"

#### Columns for square pulse ####
data_filename=1
p_tran=2
p_tran_err=3
od_used=4
photon_no=5
photon_err=6
p_refl_flou=7
p_refl_flou_err=8
p_refl_flou_bg=9
p_refl_flou_bg_err=10
p_refl_scat=11
p_refl_scat_err=12
flou_lifetime=13
flou_lifetime_err=14
max_p_refl=15
max_p_refl_err=16

#### "Columns for exponential pulse ####
exp_risetime=17
exp_risetime_err=18
fit_lambda=19
fit_lambda_err=20
fit_photon_no=21
fit_photon_err=22

#### End "Columns ####

currentdir="`pwd`"
cd rootdir

#### Styles ####

set style line 1 lc 1 lw 3
set style line 2 lc 3 lw 3
set style line 3 lc 4 lw 3

#### Normalising detection probablity to rho 22 ####
timebin=1.0
timebin8=8.0
lifetime=26.3
effiency=0.3
overlap=0.03
rho(x)=x/(overlap*effiency*(timebin/lifetime))
rho_d(x)=x/(overlap*effiency)
rho8(x)=x/(overlap*effiency*(timebin8/lifetime))
rho_d8(x)=x/(overlap*effiency)


unset logscale xy
set logscale x
set key left


#### Plotting maximum probability of detector click vs average photon number
#### MACROS

# x- and ytics for each row resp. column
set macros

NOXTICS = "set xtics; set format x ''; unset xlabel"

XTICS = "set xtics; set format x '10^{%L}'; set xlabel '{/Symbol \341}N{/Symbol \361}' offset 0,0.3"

NOYTICS = "set format y ''; unset ylabel"

YTICS = "set format y '%.1f'; set ylabel 'P_{e,max}' offset 1,0"

TMARGIN = "set tmargin at screen 0.95; set bmargin at screen 0.55"
BMARGIN = "set tmargin at screen 0.5; set bmargin at screen 0.12"
LMARGIN = "set lmargin at screen 0.12; set rmargin at screen 0.52"
RMARGIN = "set lmargin at screen 0.55; set rmargin at screen 0.95"

set yrange [0:1]
y_stretch=1e0
#set xlabel 'N' font 'Helvetica, 20'
#set ylabel 'P_{e,max}' font 'Helvetica, 20'
#set xtics font 'Helvetica, 20'
#set ytics font 'Helvetica, 20'
set terminal postscript enhanced color eps size 8.6cm,6cm font "Helvetica,16pt"
set output '../rho22_max_p_vs_n_a.eps'
set key at 200,0.24
unset label
set multiplot layout 2,2

## GRAPH 1

@NOXTICS ; @YTICS ; @TMARGIN ; @LMARGIN
set label 1 "{/Symbol t} = 5 ns" at graph 0.05,0.88
set label 2 "exp" at 5,0.6 tc lt 3
set label 3 "square" at 200,0.3 tc lt 1
set xrange [1:9000]

plot square.'5ns/'.filename u (column(photon_no)):(rho(column(max_p_refl))*y_stretch):photon_err:(rho(column(max_p_refl_err))*y_stretch) \
     w xyerror axes x1y1 pt 7 ps 1 lt 1 lc 1 lw 1 notitle,\
     exp.'5ns/'.filename u (column(photon_no)):(rho(column(max_p_refl))*y_stretch):photon_err:(rho(column(max_p_refl_err))*y_stretch) \
     w xyerror axes x1y1  pt 6 ps 1 lt 1 lc 3 lw 1 notitle,\
     '../theory_plots/raw_data/evss_pmax_n/pmax_003_5.txt' u 1:2 \
     w l lc 3 lw 2 lt 1 notitle,\
     '../theory_plots/raw_data/evss_pmax_n/pmax_003_5.txt' u 1:3 \
     w l lc 1 lw 2 lt 1 notitle

## GRAPH 2

@NOXTICS ; @NOYTICS ; @TMARGIN ; @RMARGIN

set label 1 "{/Symbol t} = 15 ns"
set label 2 "exp" at 5,0.6 tc lt 3
set label 3 "square" at 100,0.3 tc lt 1
set xrange [1:10000]

plot square.'15ns/'.filename u (column(photon_no)):(rho(column(max_p_refl))*y_stretch):photon_err:(rho(column(max_p_refl_err))*y_stretch) \
     w xyerror axes x1y1 pt 7 ps 1 lt 1 lc 1 lw 1 notitle,\
     exp.'15ns/'.filename u (column(photon_no)):(rho(column(max_p_refl))*y_stretch):photon_err:(rho(column(max_p_refl_err))*y_stretch) \
     w xyerror axes x1y1  pt 6 ps 1 lt 1 lc 3 lw 1 notitle,\
     '../theory_plots/raw_data/evss_pmax_n/pmax_003_15.txt' u 1:2 \
     w l lc 3 lw 2 lt 1 notitle,\
     '../theory_plots/raw_data/evss_pmax_n/pmax_003_15.txt' u 1:3 \
     w l lc 1 lw 2 lt 1 notitle


## GRAPH 3

@XTICS ; @YTICS ; @BMARGIN ; @LMARGIN

set label 1 "{/Symbol t} = 60 ns"
set label 2 "exp" at 300,0.4 tc lt 3
set label 3 "square" at 50,0.88 tc lt 1
# unset label 2
# unset label 3
set xrange [1:9000]

plot square.'60ns/'.filename u (column(photon_no)):(rho(column(max_p_refl))*y_stretch):photon_err:(rho(column(max_p_refl_err))*y_stretch) \
     w xyerror axes x1y1 pt 7 ps 1 lt 1 lc 1 lw 1 notitle,\
     exp.'60ns/'.filename u (column(photon_no)):(rho(column(max_p_refl))*y_stretch):photon_err:(rho(column(max_p_refl_err))*y_stretch) \
     w xyerror axes x1y1  pt 6 ps 1 lt 1 lc 3 lw 1 notitle,\
     '../theory_plots/raw_data/evss_pmax_n/pmax_003_60.txt' u 1:2 \
     w l lc 3 lw 2 lt 1 notitle,\
     '../theory_plots/raw_data/evss_pmax_n/pmax_003_60.txt' u 1:3 \
     w l lc 1 lw 2 lt 1 notitle

## GRAPH 4

@XTICS ; @NOYTICS ; @BMARGIN ; @RMARGIN

set label 1 "{/Symbol t} = 250 ns"
set label 2 "exp" at 400,0.2 tc lt 3
set label 3 "square" at 10,0.55 tc lt 1
set xrange [1:10000]

plot square.'250ns/'.filename8 u (column(photon_no)):(rho8(column(max_p_refl))*y_stretch):photon_err:(rho8(column(max_p_refl_err))*y_stretch) \
     w xyerror axes x1y1 pt 7 ps 1 lt 1 lc 1 lw 1 notitle,\
     exp.'250ns/'.filename8 u (column(photon_no)):(rho8(column(max_p_refl))*y_stretch):photon_err:(rho8(column(max_p_refl_err))*y_stretch) \
     w xyerror axes x1y1  pt 6 ps 1 lt 1 lc 3 lw 1 notitle,\
     '../theory_plots/raw_data/evss_pmax_n/pmax_003_250.txt' u 1:2 \
     w l lc 3 lw 2 lt 1 notitle,\
     '../theory_plots/raw_data/evss_pmax_n/pmax_003_250.txt' u 1:3 \
     w l lc 1 lw 2 lt 1 notitle

unset multiplot
unset output