set termoption dash

set style line 1 lt 2 lc rgb "black" lw 1
set style line 2 lt 8 lc rgb "black" lw 1
set style line 3 lt 4 lc rgb "black" lw 1
set style line 4 lt 1 lc rgb "blue" lw 1
set style line 5 lt 1 lc rgb "red" lw 1
set style line 6 lt 1 lc rgb "black" lw 2
set style line 7 lt 1 lc rgb "blue" lw 2

set key font "Helvetica,16"

set xlabel 'Polarizer Orientation, {/Symbol q} ({/Symbol \260})' font "Helvetica,18"
set ylabel 'Count Rate (s^-^1)' font "Helvetica,18"
show xlabel
show ylabel

set grid
set xtics ("-90{/Symbol \260} (V)" -90, "-45{/Symbol \260}" -45, "0{/Symbol \260} (H)" 0, "+45{/Symbol \260}" 45, "90{/Symbol \260} (V)" 90) font "Helvetica,16"
#set ytics -0.2,0.1,0.4 font "Helvetica,16"
set xrange [-90:90]
set yrange [0:260]

#set label 1 '{/Symbol a}_1 = +45{/Symbol \260}' at -6.5,210
#set label 2 '{/Symbol a}_1 = 0{/Symbol \260}' at -34,160
#set arrow 1 from -7.5,210 to -22.5,210 filled
#set arrow 2 from -35,160 to -48,160 filled

set label 3 'V_{HV} = 99.9 {/Symbol \261} 0.1%' at -85, 20 font "Helvetica,16"
set label 4 'V_{45} = 99.9 {/Symbol \261} 0.1%' at -85, 10 font "Helvetica,16"

a(x) = a1*sin(x*2*3.142/(x*a4 + a5)) + a2*cos(x*2*3.142/(x*a4 + a5)) + a3
b(x) = b1*sin(x*2*3.142/(x*b4 + b5)) + b2*cos(x*2*3.142/(x*b4 + b5)) + b3

a1 = -38.2669
a2 = -1202.4
a3 = 1203.25
a4 = 0.0222607
a5 = 190.069

b1 = -1096.07
b2 = -25.3166
b3 = 1097.74
b4 = -0.0339475
b5 = 182.653

fit a(x) '0_19064_visibility_20141202.dat' using 1:($5/10):(sqrt($5/10)) via a1, a2, a3, a4, a5
fit b(x) '0_46846_visibility_20141202.dat' using 1:($5/10):(sqrt($5/10)) via b1, b2, b3, b4, b5

#plot '0_19064_visibility_20141202.dat' using 1:($5/10) ls 4 title '',\
     '0_46846_visibility_20141202.dat'using 1:($5/10) ls 5 title '',\
      a(x) ls 6 title '', b(x) ls 7 title ''
      
plot '0_19064_visibility_20141202.dat' using 1:($5/10):(sqrt($5/10)) ls 4 title '' with yerrorbars,\
     '0_46846_visibility_20141202.dat'using 1:($5/10):(sqrt($5/10)) ls 5 title '' with yerrorbars,\
      a(x) ls 4 title 'H/V visibility', b(x) ls 5 title '+45{/Symbol \260}/-45{/Symbol \260} visibility'

set terminal postscript enhanced color
set output 'h_45_visibility_curve.eps'
replot