# reset
# set terminal svg fname "Arial" fsize 20.8 size 850 650
# set output "vio.svg"
set terminal postscript eps color enhanced size 8.6cm,5.5cm font "Helvetica,16pt"
set output "vio2.eps"

set multiplot
set origin 0,0; set size 0.75,1

unset key
set border 3
set xtics 10
set mxtics 2
set ytics 0.1
set xtics nomirror
set ytics nomirror
set xrange [1970:2019]
set yrange [2:2.89]
set clip two # allows gnuplot to draw the line even if its end points are out of range
set style line 3 default
# photonic stuff - red
set style line 3  ps .8 lt 1 lc rgbcolor "red" pt 6 lw 1
set style arrow 3 nohead lc rgbcolor "red" lt 1 lw 1
# Atom stuff
set style line 4 default
set style line 4  ps .8 lt 1 lc rgbcolor "blue" pt 12 lw 1
set style arrow 4 nohead lc rgbcolor "blue" lt 1 lw 1
#Josephson
set style line 5 default
set style line 5  ps .8 lt 1 lc rgbcolor "#800080" pt 4 lw 1
set style arrow 5 nohead lc rgbcolor "#800080" lt 1 lw 1
#NV centers
set style line 6 default
set style line 6  ps .8 lt 1 lc rgbcolor "#008000" pt 10 lw 1
set style arrow 6 nohead lc rgbcolor "#008000" lt 1 lw 1

set label "Tsirelson bound" at 1980,2.86

set ylabel "Bell parameter S" offset 1
plot  'photonic.dat' u 1:2:3 with yerrorbars ls 3, \
     'photonic.dat' using ($1+$5*2):($2+$6):8 with labels ls 3, \
     'Atom.dat' u 1:2:3 with yerrorbars ls 4, \
     '' using ($1+$5*2):($2+$6):8 with labels ls 4, \
     'JosephsonJn.dat' u 1:2:3 with yerrorbars ls 5, \
     '' using ($1+$5*2):($2+$6):8 with labels ls 5, \
     'NV.dat' u 1:2:3 with yerrorbars ls 6, \
     '' using ($1+$5*2):($2+$6):8 with labels ls 6, \
     2.828427 w l lt 2 lc rgbcolor "black" lw 1  

# 'photonic.dat' using ($1-50):2:(100):(0) with vectors arrowstyle 3,
#     'Atom.dat' using ($1-50):2:(100):(0) with vectors arrowstyle 4,
#     'JosephsonJn.dat' using ($1-50):2:(100):(0) with vectors arrowstyle 5, 
#     'NV.dat' using ($1-50):2:(100):(0) with vectors arrowstyle 6,


# second plot
set origin 0.65,0; set size 0.42,1

unset label
unset ylabel
unset y2label
set xrange [2011.5:2015.5]
set y2range [2.80:2.86]
set y2tics nomirror
set y2tics 0.01 
unset ytics
set xtics 17
set mxtics 0.5
set format y2 "%4.3g"
set border 8
# hand-written labels in zoom
set label 1 "10" at second 2013, second 2.83
set label 2 "11" at second 2014.15, second 2.823
set label 3 "*" at second 2014.8, second 2.829

plot  '-' u 1:2 w l lt 1 lc rgbcolor "black" axes x1y2 , \
      '-' u 1:3 w l lt 1 lc rgbcolor "black" axes x1y2 , \
      'photonic.dat' u 1:2:3 with yerrorbars ls 3 axes x1y2 , \
      '-' u 1:2 w l lt 2 lc rgbcolor "black" lw 1 axes x1y2
      2011.5 2.85393 2.857977
      2012   2.85393 2.857977
      2013   2.8 2.86
      2014.5 2.8 2.86
EOF
      2011.5 2.85393 2.857977
      2012   2.85393 2.857977
      2013   2.8 2.86
      2014.5 2.8 2.86
EOF
      2013.5 2.82843
      2015.5 2.82843
EOF