# reset
# set terminal svg fname "Arial" fsize 20.8 size 850 650
# set output "vio.svg"
set terminal postscript eps color enhanced size 8.6cm,6cm font "Helvetica,16pt"
set output "vio.eps"

unset key
set border 3
set xtics 10
set mxtics 2
set ytics 0.1
set xtics nomirror
set ytics nomirror
set xrange [1970:2018]
set yrange [2:2.89]
set clip two # allows gnuplot to draw the line even if its end points are out of range
set style line 3 default
# photonic stuff
set style line 3  ps 1 lt 1 lc rgbcolor "#00c000" pt 6 lw 1
set style arrow 3 nohead lc rgbcolor "#00c000" lt 1 lw 1
# Atom stuff
set style line 4 default
set style line 4  ps 1 lt 1 lc rgbcolor "blue" pt 12 lw 1
set style arrow 4 nohead lc rgbcolor "blue" lt 1 lw 1
#Josephson
set style line 5 default
set style line 5  ps 1 lt 1 lc rgbcolor "magenta" pt 4 lw 1
set style arrow 5 nohead lc rgbcolor "magenta" lt 1 lw 1
#NV centers
set style line 6 default
set style line 6  ps 1 lt 1 lc rgbcolor "red" pt 10 lw 1
set style arrow 6 nohead lc rgbcolor "red" lt 1 lw 1

set label "Tsirelson bound" at 1995,2.86

set ylabel "Bell parameter S" offset 1
plot  'photonic.dat' u 1:2:3 with yerrorbars ls 3, \
     'photonic.dat' using ($1+$5):($2+$6):4 with labels ls 3, \
     'Atom.dat' u 1:2:3 with yerrorbars ls 4, \
     '' using ($1+$5):($2+$6):4 with labels ls 4, \
     'JosephsonJn.dat' u 1:2:3 with yerrorbars ls 5, \
     '' using ($1+$5):($2+$6):4 with labels ls 5, \
     'NV.dat' u 1:2:3 with yerrorbars ls 6, \
     '' using ($1+$5):($2+$6):4 with labels ls 6, \
     2.8284 w l lt 2 lc rgbcolor "black" lw 1  

# 'photonic.dat' using ($1-50):2:(100):(0) with vectors arrowstyle 3,
#     'Atom.dat' using ($1-50):2:(100):(0) with vectors arrowstyle 4,
#     'JosephsonJn.dat' using ($1-50):2:(100):(0) with vectors arrowstyle 5, 
#     'NV.dat' using ($1-50):2:(100):(0) with vectors arrowstyle 6,