# set terminal postscript eps color enhanced solid font 'Helvetica, 16pt'\
#  size 8.6cm, 7.5cm  dl .5
set terminal postscript eps enhanced color size 8.6cm, 6cm dl 3\
font "Helvetica, 16pt"

set output '2ph_fit.eps'
set nobars

LAB_x = .05
LAB_y = .9

# overall style commands
set multiplot layout 2,1
set key off
set rmargin at screen 0.95
set lmargin at screen 0.15


#### first plot, trace

set border 31

# alignment
set bmargin at screen 0.3

#labels
set label '(a)' at graph LAB_x, graph LAB_y font 'Helvetica, 16pt'
set ylabel 'Signal (mV)' offset 1,0

#ranges
set yrange [-7: 34]
set xrange [-2: 4.5]

# tics
set xtics scale 0
set x2tics
set ytics 10
set format x ''
set format x2 ''

plot 'lmfit_raw_data_and_components.dat' u 1:5 w lines lw 4 lc 'orange', \
    'lmfit_raw_data_and_components.dat' u 1:3 w lines lw 3 lc 'blue', \
    'lmfit_raw_data_and_components.dat' u 1:4 w lines lw 3 lc 'red', \
    'lmfit_raw_data_and_components.dat' u 1:2 w lines lw 1 lc 'black'

# clean up specific settings
unset label
unset format x
unset xtics
unset x2tics
##### bottom plot, fit initialisation

# remove top border
set border 11

# align the plot with top one
set tmargin at screen 0.3
set bmargin at screen 0.15

# hight of the logic steps. Purely aesthetic
SETP_H = 0.7

# labels
unset label
set ylabel font 'Helvetica, 16pt' "Excitation (V)" offset 0, 0
set xlabel font 'Helvetica, 16pt' 'Time ({/Symbol m}s)' offset 1
set label '(b)' at graph LAB_x, graph .8

# ranges
# set xrange [-2: 4.5]
set yrange [0:5]

# tics
set ytics 3
set xtics nomirror
#set ytics nomirror scale 0
#set format y '   '

# plot
plot 'diode_pulse_separated_240ns.dat' u ($1 * 1e-3):($2 * -1) w l lw 3

#from: /disk0/home/jianwei_leejw/analysis/20170405_TES5_SQ1_fit_accuracy_80mK_iBias_104uA_7.2GHZ_100kOhm_cwscript_results/240ns