set terminal postscript eps color enhanced solid font 'Helvetica, 16pt'\
 size 8.6cm, 7.5cm  dl .5


set output 'discriminator.eps'
set nobars
THRESH = 9.609693088026121863
Ax = 3.279181254575458948e-01
Bx = 1.695918086767863597e+00
Cx = 2.199181285119944651e-01
Dx = 1.227918100003807522e+00
Ex = 2.927918051924524256e+00

LAB_x = .05
LAB_y = .9


# overall style commands
set multiplot layout 2,1
set key off
set rmargin at screen 0.91


#### first plot, trace

set border 31

# alignment
set bmargin at screen 0.6

# labels
set label '(a)' at graph LAB_x, graph LAB_y font 'Helvetica, 16pt'
set label 'V_{high}' at 4.6, THRESH font 'Helvetica, 16pt'
set label 'V_{low}' at 4.6, 0 font 'Helvetica, 16pt'
set label 'A' at Ax -.2, THRESH + 2 font 'Helvetica, 16pt' front
set label 'B' at Bx +.1, -2.5 font 'Helvetica, 16pt' front
set label 'C' at Cx + 0.12, -2 font 'Helvetica, 16pt' front
set label 'D' at Dx + 0.1, THRESH + 2 font 'Helvetica, 16pt' front
# set label 'E' at Ex + 0.1, 0 - 3 font 'Helvetica, 16pt'
set ylabel 'Signal (mV)' font 'Helvetica, 16pt' offset 1
unset xlabel

#ranges
set yrange [-6:30]
set xrange [-2:4.5]

# tics
set xtics scale 0
set x2tics
set format x ''
set format x2 ''

set ytics 10


# plot
plot \
    THRESH w lines  lw 3 lc 'grey' notitle,\
    0 w lines  lw 3 lc 'grey' notitle,\
    'demo_trace.dat' u ($1 * 1e6):($2 * 1e3) w lines lw 3 lc 'black' notitle,\
    '+' u (Ax):(THRESH) w point pt 7 lc 'blue' notitle,\
    '+' u (Dx):(THRESH) w point pt 7 lc 'red' notitle,\
    '+' u (Cx):(0) w point pt 7 lc 'red' notitle,\
    '+' u (Bx):(0) w point pt 7 lc 'blue' notitle



# clean up specific settings
unset label
unset format x
unset xtics
unset x2tics

##### bottom plot, qualifier

# remove top border
set border 11

# align the plot with top one
set tmargin at screen 0.6
set bmargin at screen 0.45

# hight of the logic steps. Purely aesthetic
SETP_H = 0.7

# labels
set label '(b) Qualifier' at graph LAB_x, graph .8
set ylabel font 'Helvetica, 16pt' ' ' offset 1

# ranges
set yrange [-0.1:1.1]

# tics
set format y '   '

# lines connecting to crossing on top plots
set arrow from Ax, SETP_H to Ax, 2.26 lw 3 lc 'grey' nohead back
set arrow from Bx, SETP_H to Bx, 1.51 lw 3 lc 'grey' nohead back

# plot
plot 'mask_forward.dat' u ($1 * 1e6):($2 * SETP_H) w lines lw 3 lc 'blue' notitle

##### bottom plot, fit initialisation
# remove top border
set border 11

# align the plot with top one
set tmargin at screen 0.45
set bmargin at screen 0.3

# hight of the logic steps. Purely aesthetic
SETP_H = 0.7

# labels
unset label 
set label '(c) Fit Initialisation' at graph LAB_x, graph .8 front
set ylabel font 'Helvetica, 16pt' ' ' offset 1

# ranges
set yrange [-0.1:1.1]

# tics
set format y '   '

# lines connecting to crossing on top plots
unset arrow
set arrow from Cx, SETP_H to Cx, SETP_H+2 lw 3 lc 'grey' nohead back
set arrow from Dx, SETP_H to Dx, SETP_H+2.76 lw 3 lc 'grey' nohead back

# plot
plot 'mask.dat' u ($1 * 1e6):($2 * SETP_H) w lines lw 3 lc 'red' notitle

##### bottom plot, fit initialisation

# remove top border
set border 11

# align the plot with top one
set tmargin at screen 0.3
set bmargin at screen 0.12

# hight of the logic steps. Purely aesthetic
SETP_H = 0.7

# labels
unset label 
set label '(d) Integration Window' at graph LAB_x, graph .8
set label 'E' at Ex + 0.1, SETP_H font 'Helvetica, 16pt'
set ylabel font 'Helvetica, 16pt' ' ' offset 1
set xlabel font 'Helvetica, 16pt' 'Time ({/Symbol m}s)' offset -1
# ranges
set yrange [-0.1:1.1]

# tics
set xtics nomirror
set ytics nomirror scale 0
set format y '   '

# lines connecting to crossing on top plots
unset arrow
set arrow from Dx, SETP_H to Dx, 1.175 lw 3 lc 'grey' nohead back
set arrow from Dx, SETP_H + 0.1 to Ex, SETP_H + 0.1 lw 3 lc 'black' heads back  
set label '{/Symbol D} t_{ext}' at (Dx + Ex)/2, SETP_H + 0.25 font 'Helvetica, 16pt' center

# plot
plot 'mask_ext.dat' u ($1 * 1e6):($2 * SETP_H) w lines lw 3 lc 'black' notitle,\
    '+' u (Ex):(SETP_H) w point pt 7 lc 'red' notitle

#from: /disk0/home/jianwei_leejw/analysis/20170405_TES5_SQ1_fit_accuracy_80mK_iBias_104uA_7.2GHZ_100kOhm_cwscript_results/240ns