set terminal postscript eps enhanced color size 8.6cm, 4cm dl 3\
font "Helvetica, 16pt"
set output 'parity_versus_separation_angle.eps'

#set termoption dash

set rmargin at screen 0.91
set style line 1 lt 1 lc rgb "black" lw 2
set style line 2 lt 1 lc rgb "brown" lw 2
set style line 3 lt 1 lc rgb "orange" lw 2
set style line 4 lt 1 lc rgb "#7570B3" lw 2
set style line 5 lt 1 lc rgb "#6495ED" lw 2
set style line 6 lt 1 lc rgb "#034E7B" lw 2

set style line 11 lt 1 pt 6 ps 1.1 lc rgb "brown" lw 3
set style line 12 lt 1 pt 4 ps 1.1 lc rgb "orange" lw 3
set style line 13 lt 1 pt 10 ps 1.4 lc rgb "#7570B3" lw 3
set style line 14 lt 1 pt 12 ps 1.4 lc rgb "#6495ED" lw 3
set style line 15 lt 1 pt 14 ps 1.4 lc rgb "#034E7B" lw 3


unset bars
set xlabel 'Angle of separation {/Symbol b} (degree)'
set ylabel 'S (A, B)' offset 2,0

V = 0.987140306297079
f(x) = V**n * (3 * cos(x/90*pi)**n - cos(3*x/90*pi)**n)

set label 111 "Parity vote" at 1, 2.7 font "Helvetica, 16pt"


set label 11 "n= 1" at 14.1, 2.53 font "Helvetica, 16pt"
set label 12 "n= 5" at 14.1, 1.55 font "Helvetica, 16pt"
set label 13 "n= 9" at 14.1, .9 font "Helvetica, 16pt"
set label 14 "n=12" at 14.1, .56 font "Helvetica, 16pt"
set label 15 "n=17" at 14.1, .3 font "Helvetica, 16pt"

set xrange [0:14]
# plot n=1, f(x) with l ls 2 notitle,\
#     n=5, f(x) with l ls 3 notitle
plot 2 w filledcurves x1 ls 1 lc rgb "#e0e0e0" notitle ,\
     2 w l ls 1 notitle, \
     n=1, f(x) with l ls 2 notitle,\
     n=5, f(x) with l ls 3 notitle,\
     n=9, f(x) with l ls 4 notitle,\
     n=12, f(x) with l ls 5 notitle,\
     n=17, f(x) with l ls 6 notitle,\
    'exp_parity_M=01.dat' u 1:(abs($2)):3 with yerrorbars ls 11 notitle, \
    'exp_parity_M=05.dat' u 1:(abs($2)):3 with yerrorbars ls 12 notitle, \
    'exp_parity_M=09.dat' u 1:(abs($2)):3 with yerrorbars ls 13 notitle, \
    'exp_parity_M=12.dat' u 1:(abs($2)):3 with yerrorbars ls 14 notitle, \
    'exp_parity_M=17.dat' u 1:(abs($2)):3 with yerrorbars ls 15 notitle

#     for [col=2:6] 'sim_parity.dat' using 1:col with l ls col notitle, \